/*データの読み込み:ドライブをxドライブを利用するものとしています。適宜修正してください*/
libname  mylib "x:\sasw" ;
DATA mylib.plpidx;
infile 'x:\sasw\SAS_AnalysisData.txt' dlm='",'  missover LRECL=1500 ;
input
ID Ken Yoto price1 price2 sq rw kenpei yosek ts UDIS cpcode gesui sui gas UX UY YearD tanka
price area Rw ts tt cp1-cp7 tm1-tm34 UXX UYY ;
run;


/*全体・記述統計量の計算1*/
PROC means DATA = mylib.plpidx;
var tanka price area Rw ts tt;
run;

/*全体・記述統計量の計算2*/
PROC univariate DATA = mylib.plpidx;
var tanka price area Rw ts tt;
run;


/*県別ソート*/
PROC sort DATA = mylib.plpidx;
by ken;
run;


/*県別・記述統計量の計算2*/
PROC univariate DATA = mylib.plpidx noprint;
var tanka;
by ken;
output out=stat n=N mean=Mean std=Std var=Var
              skewness=Skewness kurtosis=Kurtosis
              mode=Mode range=Range
              max=Max min=Min p99=p99 p95=p95 p90=p90
              q3=p75 median=p50 q1=p25 p10=p10 p5=p5 p1=p1;
run;

/*県別・記述統計量出力*/
PROC EXPORT DATA=stat
            OUTFILE= "x:\sasw\SummaryStat.csv"
            DBMS=CSV REPLACE;
RUN;

/*回帰分析:地域別回帰*/
PROC REG DATA = mylib.plpidx outest=reg adjrsq noprint;
  MODEL price= tm2-tm34 area rw ts tt gesui sui gas UX UY UXX UYY cp1 cp3 cp6 cp7 ;
by ken;
run;
quit;

/*回帰分析:地域別回帰出力*/
PROC EXPORT DATA=reg
            OUTFILE= "x:\sasw\hedonicindex.csv"
            DBMS=CSV REPLACE;
RUN;